Showing: heuristic.xom

As of:  Thu 2010-09-02 18:05:51 UTC  [=1283450751. 14:05:51-04:00]

>> heuristic.xom  L: 4,536. A: 100444. M: 1999-06-01 18:55:28 UTC [=928263328] -4110.96d >> 

down-translate

; omle sgmlset.txt heuristic.sgm -s heuristic.xom -of heuristic.html

global stream version initial {"1.31, 01 June 1999"}
global stream html
global stream mydate
global stream security
global stream monames variable initial-size 12  initial {"January", "February",
           "March", "April", "May", "June", "July", "August", "September",
           "October", "November", "December"}

document-start
    open html as file "heuristic.html"
    put html "<!DOCTYPE HTML PUBLIC %"-//W3C//DTD HTML 3.2//EN%">%n<html><head>%n"
    put html "<title>Formatted version of SGML file</title>%n"
    put html "</head>%n"
    put html "<body bgcolor=%"silver%">%n"

document-end
    put html "<p>%n"
    put html "</body></html>%n"
    close html
    put #process-output "Normal end of job: heuristic.xom, ver: %g(version)%n"

translate '<' => amp
;    put html "%x(amp)"
    put html "&lt;"
    

element heuristic
    local stream ls
    set security to "%v(security)"
    do when security = "UNRESTRICTED" or security = "INTERNAL"
        set security to "<font color=%"green%">(This document is for %g(security) distribution.)</font>"
    else
        set security to "<font color=%"red%">This document is classified: %g(security)!</font>"
    done
    set ls to "%c"

element purpose
    put html "<h1><font color=%"navy%">%c</font></h1>%n"
    put html "<h3>%g(security)</h3>%n"

element realization
    local stream ls
    set ls to "%c"

element point
    local stream ls
    set ls to "%c"
    
element title
    put html "<h2><font color=%"navy%">%c</font></h2>%n"

element text
    put html "<p><font size=%"+1%">%c</font></p>%n"

element docinfo
;    local stream ls
;    set ls to "%c"
    put html "<p><hr size=%"7%"><font size=%"+1%">%n"
    put html "<a href=%"WhatIsSGML.html%">Return</a> to <i>SGML document introducing you to SGML</i><br>%n"
    put html "<a href=%"sgmlnote.html%">Go</a> to <i>*Darwin Among the Machines* (Suzanne Langer and SGML)</i> page</font>%n"
    put html "<hr width=%"40%%%" align=%"left%"><font size=%"+1%">%n"
    put html "<a href=%"Bradsmap.htm%"><img src=%"signpost.gif%"%n"
    put html "align=right height=32 width=32 vspace=0 hspace=5 border=0 alt=%"[ Go to Site Map! ]%"></a>%n"
    put html "<a href=%"welcome.html%">Return</a> to Brad McCormick's home page<br>%n"
    put html "<a href=%"Bradsmap.htm%">Go</a> to Brad McCormick's <i>website map</i>%n"
    put html "</font><hr>%n"
    put html "<A HREF=%"http://validator.w3.org/%"><IMG SRC=%"valid_html3_2.gif%"%n"
    put html "height=32 width=48 align=right hspace=4 vspace=2 border=0%n"
    put html "ALT=%"[ HTML 3.2 Checked! Test me! ]%"></A>"
    put html "<address>%c</address><br>%n"

element url
    local stream ls
;    set ls to "%c"
    put html "http://%c"

element server
    put html "%c/"

element account
    put html "~%c/"

element page.id
    put html "%c<br>%n"
    put html "(Page generated by OmniMark script: heuristic.xom, v%g(version))%n"

element author
    put html "<br>%c%n"

element given.name
    put html "%c "

element sur.name
    put html "%c"

element credential
    put html ", %c"

element auth.eaddr
    put html "<br>%c%n"

element rev.date
    local stream lc
;    open stream mydate as buffer
    set mydate to ""
    set lc to "%c"
;    close mydate
    put html "<br>%g(mydate)%n"

element rev.yr
    set mydate to "%c"

element rev.da
    set mydate to "%c %g(mydate)"
   
element rev.mo
    local stream ls
    local counter i
    set i to "%c" 
    set ls to monames item i
    set mydate to "%g(ls) %g(mydate)" 

element list
    do when parent is "TEXT"
        put html "</font></p><ul>%c</ul><p><font size=%"+1%">%n"
    else when parent is "ITEM"
        put html "</font><ul>%c</ul><font size=%"+1%">%n"
    done

element item
    put html "%n<li><font size=%"+1%">%c</font>"

element quote
    do when "%v(type)" = "TEXT.AS.OBJECT"
        put html "%"<font color=%"purple%">%c</font>%""
    else
        put html "%"%c%""
    done
    do when attribute source isnt implied
        put html " (--%v(source))"
    done

element institution
    put html "<b>%c</b>"

element country
    put html "%c"

element ruler
    put html "%v(type) %c"

element product
    put html "<b>%c</b>&copy;"

;element i
;    put html "<i><font color=%"blue%">%c</font></i>"

element inote
    put html "<font size=%"+1%" color=%"blue%"><i>%c</i></font>%n<p>%n<hr>%n"

element link
    put html "<i><font color=%"green%">%c</font></i>"

element #implied
    put #process-output "{.%c.}"

<< heuristic.xom  L: 4,536. A: 100444. M: 1999-06-01 18:55:28 UTC [=928263328] -4110.96d <<
Some systems do not provide this script with a return address (the HTTP_REFERER cgi environment variable). In those cases, the "Return" icon at right is disabled, but you can still use your web browser's BACK button to return to the page from which you came to here. I apologize. Thank you for your understanding.
Page generated by:
http://www.users.cloud9.net/~bradmcc/cgi-bin/ascii.pl?f=heuristic.xom
Copyright © 2001-2005 Brad McCormick, Ed.D.
bradmcc@cloud9.net
26 April 2008CE
v10.05